awk - grep does not work in removing patterns from a file from a CSV

Question

I have a file which needs too be cleaned of some URLs. The URLs are in a file say fileA and the CSV fileB(these are huge files of size 6-10 GB). I have tried the following grep command, but it does not work on newer fileB's.

grep -vwF -f patterns.txt fileB.csv > result.csv

The structure of file A is a single list of URLs like so:

URLs (header, single column)
bwin.hu
paradisepoker.li

and fileB:

type|||URL|||Date|||Domain
1|||https://www.google.com|||1524024000|||google.com 
2|||www.bwin.hu|||1524024324|||bwin.hu

The delimiter for fileB is |||

I am open to all solutions including awk. Thanks.

Edit: expected output is the CSV file retaining all rows not matching the domain patterns in fileA

type|||URL|||Date|||Domain
1|||https://www.google.com|||1524024000|||google.com 

Answer 1

Could you please try following.

awk 'FNR==NR{a[$0];next} !($NF in a)' Input_filea FS="\|\|\|" Input_fileb

OR

awk 'FNR==NR{a[$0];next} !($NF in a)' filea FS='|||' fileb

Output will be as follows.

type|||URL|||Date|||Domain
1|||https://www.google.com|||1524024000|||google.com 

Explanation: Adding explanation for above code now.

awk '                                          ##Starting awk program here.
FNR==NR{                                       ##Checking condition FNR==NR which will be TRUE when first Input_file named filea is being read.
  a[$0]                                        ##Creating an array named a whose index is $0(current line).
  next                                         ##next keyword will skip all further statements.
}                                              ##Closing block for condition FNR==NR here.
!($NF in a)                                    ##Checking condition if last field of current line is NOT present in array a for Input_fileb only.
                                               ##if condition is TRUE then no action is mentioned so by default print of current line will happen.
' filea FS="\|\|\|" fileb                   ##Mentioning Input_file names and for fileb mentioning FS should be ||| escaped it here so that awk will consider it as a literal character.