.net - Retrieve ALL cookies from Internet Explorer

Question

I'm trying to retrieve all cookies that are associated with a specific page I have open (I've already authenticated). There are several cookies associated with the webpage, I need to retrieve each cookie in order to do a POST later on.

I've tried several approaches, but none have given me the full list. I've written the code thus far in VBA, but I'm fine with it being in .NET as well.

First attempt, after getting the pointer to IE.

arraycookie = Split(ie.document.Cookie, ";")

For i = LBound(arraycookie) To UBound(arraycookie)
    Debug.Print arraycookie(i)
Next i

This gives me some of the cookies, but not all of them. I can review the cookies in the developer tools (F12) and I confirmed no cookies have the HTTP only Flag marked. See the picture below.

I also tried the InternetGetCookie windows API. It's returning a cookie, but only one, and it's the same one no matter what the name is (e.g. FedAuth below).

Private Sub GetCookieAttempt()
Dim sCookieVal As String * 256
Dim bRet As Boolean
bRet = InternetGetCookie("https://mywebsiteaddresshere.com", _
    "FedAuth", sCookieVal, 255)
    If bRet = False Then
        MsgBox "Failed"
    Else
        MsgBox sCookieVal
    End If
End Sub

This is just a guess (any idea how I could find out?), but from what I read it may be that the cookie is protected. I took a look at the IEGetProtectedModeCookie API, but I couldn't get it to return cookie information.

Not sure why I can see this through developer tools, but when I try and expose the information, it doesn't return everything.

Any help would be greatly appreciated :)

Thanks!

---

Edit

So after digging around this issue I thought I'd try the same webpage with a different browser and review the cookie details again.

Using Firebug the cookies I was trying to retrieve is now showing an HTTPOnly flag. From what I understand I can use InternetGetCookieEx with the INTERNET_COOKIE_HTTPONLY flag specified. However I can't get it to return anything.

Does anyone have a working sample I can follow?

Answer 1

Try to retrieve IE cookies from shell:cookies folder. There is the below code as an example:

Option Explicit

Sub GetIECookies()

    Dim sCookiesPath As String
    Dim oCookies As Object
    Dim oFSO As Object
    Dim oFolder As Object
    Dim oFile
    Dim sContent As String
    Dim a() As String
    Dim i As Long
    Dim aItems
    Dim aCookies()

    ' read IE cookie files
    sCookiesPath = CreateObject("shell.application").Namespace("shell:Cookies").self.Path
    Set oCookies = CreateObject("Scripting.Dictionary")
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFSO.GetFolder(sCookiesPath)
    For Each oFile In oFolder.Files
        If LCase(oFSO.GetExtensionName(oFile.Name)) = "txt" Then
            With oFile.OpenAsTextStream(1, 0) ' read-only, ascii
                sContent = .ReadAll
                .Close
            End With
            sContent = Replace(sContent, vbCr, "")
            ' split cookies within file
            a = Split(sContent, vbLf & "*" & vbLf)
            For i = 0 To UBound(a) - 1
                oCookies.Add oCookies.Count, a(i)
            Next
        End If
    Next
    ' parse data, repack to 2d array
    aItems = oCookies.Items()
    If UBound(aItems) = -1 Then
        MsgBox "No cookies found"
    Else
        ReDim aCookies(1 To UBound(aItems) + 1, 1 To 6)
        For i = 1 To UBound(aItems) + 1
            a = Split(aItems(i - 1), vbLf)
            aCookies(i, 1) = a(0)
            aCookies(i, 2) = a(1)
            aCookies(i, 3) = a(2)
            aCookies(i, 4) = GetInetCookieFlags(a(3))
            aCookies(i, 5) = ConvDT(a(4), a(5))
            aCookies(i, 6) = ConvDT(a(6), a(7))
        Next
        ' output
        With ThisWorkbook.Sheets(1)
            .Cells.Delete
            .Range("A1:F1") = Array("Name", "Value", "Host/Path", "Flags", "Expiration", "Created")
            Output .Range("A2"), aCookies
        End With
    End If

End Sub

Function ConvDT(sLowNTFmt As String, sHighNTFmt As String) As Date

    Dim dNTFmt As Double
    Dim dUnixFmt As Double

    ' FILETIME format is the number of 100 nanosecond ticks since 00:00 1 Jan, 1601 (UTC).
    dNTFmt = sHighNTFmt * 4294967296# + sLowNTFmt
    ' Unix time format is the number of seconds since 00:00 1 Jan 1970
    dUnixFmt = 0.0000001 * dNTFmt - 11644473600#
    ' VB time format is the number of days since 00:00 1 Jan 1900
    ConvDT = CDate(dUnixFmt / 86400 + 25569)

End Function

Function GetInetCookieFlags(sFlags As String) As String

    Dim lFlags As Long
    Dim aFlag

    ' reset bit 32 to avoid overflow
    If sFlags >= 2147483648# Then lFlags = CLng(sFlags - 2147483648#) Else lFlags = CLng(sFlags)
    ' convert flags bits to string representation
    With CreateObject("Scripting.Dictionary")
        For Each aFlag In Array( _
            Array(&H1, "IS SECURE"), _
            Array(&H2, "IS SESSION"), _
            Array(&H10, "THIRD PARTY"), _
            Array(&H20, "PROMPT REQUIRED"), _
            Array(&H40, "EVALUATE P3P"), _
            Array(&H80, "APPLY P3P"), _
            Array(&H100, "P3P ENABLED"), _
            Array(&H200, "IS RESTRICTED"), _
            Array(&H400, "IE6"), _
            Array(&H800, "IS LEGACY"), _
            Array(&H1000, "NON SCRIPT"), _
            Array(&H2000, "HTTPONLY"), _
            Array(&H4000, "HOST ONLY"), _
            Array(&H8000, "APPLY HOST ONLY"), _
            Array(&H20000, "RESTRICTED ZONE"), _
            Array(&H20000000, "ALL COOKIES"), _
            Array(&H40000000, "NO CALLBACK"), _
            Array(&H80000000, "ECTX 3RDPARTY") _
        )
            If lFlags And aFlag(0) Then .Add .Count, aFlag(1)
        Next
        GetInetCookieFlags = Join(.Items(), vbCrLf)
    End With

End Function

Sub Output(oDstRng As Range, aCells As Variant)

    With oDstRng
        .Parent.Select
        With .Resize( _
            UBound(aCells, 1) - LBound(aCells, 1) + 1, _
            UBound(aCells, 2) - LBound(aCells, 2) + 1 _
        )
            .NumberFormat = "@"
            .Value = aCells
            .Columns.AutoFit
        End With
    End With

End Sub

The output for me after deleting all cookies and navigating to https://stackoverflow.com/ is as follows:

Some notes regarding the code.

It parses files in Cookies folder only, but not in CookiesLow which is for applications running under low privileges. It retrieves persistent cookies stored in the folder only, but not session cookies, which are stored in memory and can be accessed only by the process that created them. Time is in UTC.

The structure of a cookie within a file is as follows:

Cookie name
Cookie value
Host/path for the web server setting the cookie
Flags
Exirpation time (low)
Expiration time (high)
Creation time (low)
Creation time (high)
Record delimiter (*)

Flags are defined as per wininet.dll headers:

#define INTERNET_COOKIE_IS_SECURE                0x00000001
#define INTERNET_COOKIE_IS_SESSION               0x00000002
#define INTERNET_COOKIE_THIRD_PARTY              0x00000010
#define INTERNET_COOKIE_PROMPT_REQUIRED          0x00000020
#define INTERNET_COOKIE_EVALUATE_P3P             0x00000040
#define INTERNET_COOKIE_APPLY_P3P                0x00000080
#define INTERNET_COOKIE_P3P_ENABLED              0x00000100
#define INTERNET_COOKIE_IS_RESTRICTED            0x00000200
#define INTERNET_COOKIE_IE6                      0x00000400
#define INTERNET_COOKIE_IS_LEGACY                0x00000800
#define INTERNET_COOKIE_NON_SCRIPT               0x00001000
#define INTERNET_COOKIE_HTTPONLY                 0x00002000
#define INTERNET_COOKIE_HOST_ONLY                0x00004000
#define INTERNET_COOKIE_APPLY_HOST_ONLY          0x00008000
#define INTERNET_COOKIE_RESTRICTED_ZONE          0x00020000
#define INTERNET_COOKIE_ALL_COOKIES              0x20000000
#define INTERNET_COOKIE_NO_CALLBACK              0x40000000
#define INTERNET_COOKIE_ECTX_3RDPARTY            0x80000000