之前兰色曾分享过Vlookup函数的12种用法，再次翻看时发现少了最常见的查询：合并单元格查询。今天把合并单元格查找的两个Vlookup公式也补充进来（例13和例14），这下Vlookup函数的用法才算完整了。

【例1】查找个人信息

=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)

注：Column(b1)的结果是2，当公式向右复制时可以生成3，4，5，..

【例2】合并两个表格

F2单元格公式

=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))

公式说明：用Match函数查找表1的标题在表2中的位置

【例3】让两个表格同类商品排序完全一样

F2单元格公式

=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),””)

公式说明：IFERROR函数用来屏蔽错误值

【例4】制作工资条

=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

公式说明：根据序号从工资表中查找对应的信息

【例5】合并N个日报表

有N个日报表，A列为销售员（每个表的销售员顺序人数不一定相同），B列是销量。现需要合并到一个表中。

由于顺序和人员不同，直接粘贴肯定不行。难道要一个一个的手工填写吗？当然不用，一个Vlookup公式即可。

B3公式：

=IFERROR(VLOOKUP($A3,INDIRECT(B$2&”!A:B”),2,0),””)

【例6】模糊查找产品名称（包含查找）

=VLOOKUP(“*”&F41&”*”,$B$41:$D$47,3,0)

注：*是通配符，代表任意多个字符

【例7】带特殊符合的字符查找

=VLOOKUP(SUBSTITUTE(F52,”~”,”~~”),B$52:C$56,2,0)

注：由于~ * ？在公式中有通配符用法，遇到被查找的字符串中含有这3个字符就用Substitute替换为~~、~*和~？

【例8】逆向查找

=VLOOKUP(G61,IF({1,0},C61:C69,B61:B69),2,)

公式说明: 本公式只做了解，遇到逆向查找，建议使用Index+Match函数。

=INDEX(B60:B69,MATCH(G61,C60:C69,0))

【例9】16年与17年单价核对，表格核对（带通配符），结果显示多N 或 少N

=TEXT(VLOOKUP(SUBSTITUTE(B73,”*”,”~*”),$F$73:$G$92,2,)-C73,“少0.00;多0.00;”)

公式说明:Text可以设置数字显示的格式

【例10】Vlookup多条件查找

A112?=B112&C112

H112?=VLOOKUP(F112&G112,A112:D120,4,0)

公式说明：Vlookup也可以使用IF({1,0}的数组形式实现多条件查找，但运行效率太慢，所以建议使用辅助列连接再查找的方法。

【例11】库存单价的监控。销售单价>库存单价时填充红色背景

设置方法：选取区域 – 条件格式 – 新建规则 – 使用公式确定… – 在下面框中输入公式：

=H2>VLOOKUP(F2,A:C,3,0)

最后点“格式”按钮设置填充色为红色

【例12】银行存款最近30天到期提醒。表中要有某天汇总金额，也要有明细金额。

设置方法：

步骤1?添加辅助列，根据到期日生成 到期日+序列（目的是对同一个日期编序号，方便Vlookup一对多查找）

=D2&”-“&COUNTIF(D$2:D2,D2)

步骤2?设置到期日公式，H2单元格输入=Today()?,H3=H2+1,然后H3公式向下复制

步骤3?设置求和公式，用来统计每个到期时需要还款的总金额

=SUMIF(D:D,H2,C:C)

步骤4?用Vlookup查找各行明细数据

J2单元格公式

=IFERROR(VLOOKUP($H2&”-“&J$1,$A:$D,2,0)&”:”&VLOOKUP($H2&”-“&J$1,$A:$D,3,0),””)

公式说明：这里把H列日期&第1行的数字作为查找内容，在A列中进行查找，然后返回?B列 & C列的数据，

【例13】查找所在部门的奖金

=VLOOKUP(VLOOKUP(“座”,D$2:D2,1),A:B,2,0)

注：VLOOKUP(“座”,D$2:D2,1)可以返回D列截止本行的最后一个非空值。

【例14】带合并单元格的多条件查找

=VLOOKUP(F2,OFFSET(B$1,MATCH(E2,A:A,)-1,):C99,2,0)

注：用Match查找出部门所在行数，然后用offset函数向下偏移B1，进尔和C99构成一个动态的区域。更简单的说就是部门在哪一行，我就用Vlookup从哪一行开始向下找。

兰色说：在实际工作中，Vlookup函数不是功能最强大的那个，但它总是最简单实用的那个。